**3.18. Загрузка данных из файла**

Подсистема «Загрузка данных из файла» предоставляет пользовательский и программный интерфейс для загрузки табличных данных из файлов в произвольные справочники и табличные части документов и справочников. Например, с ее помощью можно предусмотреть перенос нормативно-справочной информации при переходе с других программ, а также быстрое заполнение табличных частей при вводе документов.

**Настройка**

**Загрузка данных в справочники**

Если в конфигурации используется подсистема «Настройки программы», рекомендуется разместить обработку ЗагрузкаДанныхИзФайла на панели администрирования Перенос данных в группе Загрузка данных. См. пример размещения в демонстрационной конфигурации в форме ПереносДанных обработки \_ДемоПанельАдминистрирования.

В противном случае необходимо разместить обработку ЗагрузкаДанныхИзФайла в рабочем месте администратора программы.

По умолчанию загрузка данных становится доступной для большинства справочников конфигурации. Однако это не всегда целесообразно. Рекомендуется запрещать загрузку данных в справочники:

● содержащие служебную, технологическую или другую информацию, изменение которой может привести к некорректной работе программы;

● которые имеют собственные механизмы автоматического обновления или заполнения. Например, классификаторы КлассификаторБанковРФ, СтраныМира и пр.;

● пакетная загрузка в которые небезопасна (например, ВнешниеПользователи, Пользователи, ТомаХраненияФайлов);

● «технологические» справочники, которые не редактируют пользователи (например, ГруппыИсполнителейЗадач, ИдентификаторыОбъектовМетаданных, ОчередьЗаданий и т. д.).

В таких случаях в модуле ЗагрузкаДанныхИзФайлаПереопределяемый в методе ПриОпределенииСправочниковДляЗагрузкиДанных следует исключать такие справочники:

Процедура ПриОпределенииСправочниковДляЗагрузкиДанных(ЗагружаемыеСправочники) Экспорт

// Загрузка в классификатор валюты запрещена

СтрокаТаблицы = ЗагружаемыеСправочники.Найти(Метаданные.Справочники.Валюты.ПолноеИмя(), "ПолноеИмя");

Если СтрокаТаблицы <> Неопределено Тогда

ЗагружаемыеСправочники.Удалить(СтрокаТаблицы);

КонецЕсли;

КонецПроцедуры

Кроме того, по умолчанию загрузка данных запрещена для справочников:

● с одной или несколькими табличными частями (кроме табличных частей с именами КонтактнаяИнформация, ДополнительныеРеквизиты, СертификатыШифрования);

● с реквизитами типа ХранилищеЗначений (например, все справочники с присоединенными файлами или с форматированными документами).

Это ограничение обусловлено тем, что стандартный механизм загрузки не позволяет загружать данные в элементы таких справочников, а загрузка только оставшейся части реквизитов может привести к некорректным результатам.

Однако если известно, что загрузка в такой справочник без заполнения этих элементов не вызовет проблем в работе программы, то можно разрешить загрузку данных, разместив в модуле ЗагрузкаДанныхИзФайлаПереопределяемый в методе ПриОпределенииСправочниковДляЗагрузкиДанных следующий код:

Процедура ПриОпределенииСправочниковДляЗагрузкиДанных(ЗагружаемыеСправочники) Экспорт

Сведения = ЗагружаемыеСправочники.Добавить();

Сведения.ПолноеИмя = Метаданные.Справочники.\_ДемоНоменклатура.ПолноеИмя();

Сведения.Представление = Метаданные.Справочники.\_ДемоНоменклатура.Представление();

Сведения.ПрикладнаяЗагрузка = Ложь;

КонецПроцедуры

Также имеется возможность переопределить стандартный механизм загрузки данных в справочники. Подробнее см. в разделе «[Особые случаи внедрения подсистемы](https://its.1c.ru/db/content/bsp301doc/src/3.18.%20%D0%B7%D0%B0%D0%B3%D1%80%D1%83%D0%B7%D0%BA%D0%B0%20%D0%B4%D0%B0%D0%BD%D0%BD%D1%8B%D1%85%20%D0%B8%D0%B7%20%D1%84%D0%B0%D0%B9%D0%BB%D0%B0.htm?_=1542292879#_особые_случаи_внедрения_1)».

**Загрузка данных в табличную часть документа или справочника**

Нужно принять решение по поводу табличных частей объектов (документов и справочников), в которых востребована пакетная загрузка данных. Например, это могут быть табличные части Товары документов поступления и реализации товаров и услуг, строки которых часто заполняются на основании первичных документов: из таблиц Microsoft Excel или файлов другого формата.

Для объектов, в которые требуется добавить возможность загрузки данных из файла в табличную часть, необходимо произвести следующие действия.

**Команда загрузки данных**

В форме объекта создать команду и разместить ее на командной панели табличной части. Например, для табличной части Товары – команду ЗагрузитьТоварыИзФайла с синонимом Загрузить из файла… Установить свойство Изменяет сохраняемые данные в Истина. Если в объекте требуется предусмотреть загрузку в несколько табличных частей, то для каждой табличной части создается отдельная команда.

Далее в форме объекта реализовать обработку команды и процедуру добавления данных в табличную часть. Пример реализации для табличной части Товары документа \_ДемоСчетНаОплатуПокупателю:

&НаКлиенте

Процедура ЗагрузитьТоварыИзФайла(Команда)

ПараметрыЗагрузки = ЗагрузкаДанныхИзФайлаКлиент.ПараметрыЗагрузкиДанных();

ПараметрыЗагрузки.ПолноеИмяТабличнойЧасти = "\_ДемоПоступлениеТоваров.Товары";

ПараметрыЗагрузки.Заголовок = НСтр("ru = 'Загрузка списка товаров из файла'");

ДополнительныеПараметры = Новый Структура();

ДополнительныеПараметры.Вставить("Контрагент", Объект.Контрагент);

ДополнительныеПараметры.Вставить("Организация", Объект.Организация);

ПараметрыЗагрузки.ДополнительныеПараметры = ДополнительныеПараметры;

Оповещение = Новый ОписаниеОповещения("ЗагрузитьТоварыИзФайлаЗавершение", ЭтотОбъект);

ЗагрузкаДанныхИзФайлаКлиент.ПоказатьФормуЗагрузки(ПараметрыЗагрузки, Оповещение);

КонецПроцедуры

&НаКлиенте

Процедура ЗагрузитьТоварыИзФайлаЗавершение(АдресЗагруженныхДанных, ДополнительныеПараметры) Экспорт

Если АдресЗагруженныхДанных = Неопределено Тогда

Возврат;

КонецЕсли;

ЗагрузитьТоварыИзФайлаНаСервере(АдресЗагруженныхДанных);

КонецПроцедуры

&НаСервере

Процедура ЗагрузитьТоварыИзФайлаНаСервере(АдресЗагруженныхДанных)

ЗагруженныеДанные = ПолучитьИзВременногоХранилища(АдресЗагруженныхДанных);

ТоварыДобавлены = Ложь;

Для каждого СтрокаТаблицы Из ЗагруженныеДанные Цикл

Если Не ЗначениеЗаполнено(СтрокаТаблицы.Номенклатура) Тогда

Продолжить;

КонецЕсли;

НоваяСтрокаТовары = Объект.Товары.Добавить();

НоваяСтрокаТовары.Номенклатура = СтрокаТаблицы.Номенклатура;

НоваяСтрокаТовары.Цена = СтрокаТаблицы.Цена;

НоваяСтрокаТовары.Количество = СтрокаТаблицы.Количество;

НоваяСтрокаТовары.ЕдиницаИзмерения = СтрокаТаблицы.ЕдиницаИзмерения;

ТоварыДобавлены = Истина;

КонецЦикла;

Если ТоварыДобавлены Тогда

Модифицированность = Истина;

КонецЕсли;

КонецПроцедуры

**Табличный макет для загрузки данных**

Далее при объекте необходимо создать табличный макет с именем ЗагрузкаИзФайла. Если в объекте предусмотрена загрузка в несколько табличных частей, то к макету добавляется имя табличной части: ЗагрузкаИзФайла<ИмяТабличнойЧасти>.

В колонках первой строки макета перечисляются представления имен колонок загружаемых данных, а в свойствах ячейки Имя следует указать имя колонки таблицы значений с загружаемыми данными.

Возможны случаи, когда один реквизит табличной части может соответствовать сразу нескольким колонкам загружаемых данных. Например, значение реквизита Номенклатура табличной части может быть заполнено по одной из колонок: Штрихкод, Артикул или Наименование. В таких случаях в свойствах ячейки макета ПараметрРасшифровки требуется указать имя реквизита табличной части, с которым связана эта колонка. Таким образом, для колонок Штрихкод, Артикул и Наименование в свойстве ячейки ПараметрРасшифровки указывается Номенклатура.

В свойстве Примечание каждой колонки первой строки макета рекомендуется написать подсказку о назначении и типе этой колонки. Например, в колонке Артикул может быть указано примечание: «Артикул товара (не более 20 символов)».

Внимание. Не допускается использование в макете колонки с именем Идентификатор. Это ограничение обусловлено тем, что механизм загрузки использует одноименную колонку для служебных целей.

См. пример макета для загрузки данных в документе \_ДемоСчетНаОплатуПокупателю.

Также имеется возможность динамически создавать шаблон с нужным набором колонок для загрузки данных в табличные части объектов. Подробнее см. в разделе «[Особые случаи внедрения подсистемы](https://its.1c.ru/db/content/bsp301doc/src/3.18.%20%D0%B7%D0%B0%D0%B3%D1%80%D1%83%D0%B7%D0%BA%D0%B0%20%D0%B4%D0%B0%D0%BD%D0%BD%D1%8B%D1%85%20%D0%B8%D0%B7%20%D1%84%D0%B0%D0%B9%D0%BB%D0%B0.htm?_=1542292879#_особые_случаи_внедрения_1)».

**Процедуры в модуле менеджера документа**

В модуле менеджера документа добавить экспортную процедуру СопоставитьЗагружаемыеДанныеИзФайла, в которой реализовать логику сопоставления загружаемых данных с данными в информационной базе:

// Производит сопоставление данных, загружаемых в табличную часть ПолноеИмяТабличнойЧасти,

// с данными в ИБ, и заполняет параметры АдресТаблицыСопоставления и СписокНеоднозначностей.

//

// Параметры:

//   ПолноеИмяТабличнойЧасти   - Строка - полное имя табличной части, в которую загружаются данные.

//   АдресЗагружаемыхДанных    - Строка - адрес временного хранилища с таблицей значений, в которой

//       находятся загруженные данные из файла. Состав колонок:

//     \* Идентификатор - Число - порядковый номер строки;

//     \* остальные колонки соответствуют колонкам макета ЗагрузкаИзФайла.

//   АдресТаблицыСопоставления - Строка - адрес временного хранилища с пустой таблицей значений,

//             являющейся копией табличной части документа,

//                                        которую необходимо заполнить из таблицы АдресЗагружаемыхДанных.

//   СписокНеоднозначностей - ТаблицаЗначений - список неоднозначных значений, для которых в ИБ имеется несколько подходящих вариантов.

//    \* Колонка       - Строка - имя колонки, в которой была обнаружена неоднозначность;

//    \* Идентификатор - Число  - идентификатор строки, в которой была обнаружена неоднозначность.

//   ДополнительныеПараметры   - ЛюбойТип - Любые дополнительные сведения.

//

Процедура СопоставитьЗагружаемыеДанные(ПолноеИмяТабличнойЧасти, АдресЗагружаемыхДанных, АдресТаблицыСопоставления, СписокНеоднозначностей, ДополнительныеПараметры) Экспорт

КонецПроцедуры

При сопоставлении данных возможны неоднозначные ситуации, когда по значениям колонок исходных (загружаемых) данных находятся сразу несколько подходящих объектов информационной базы и поэтому невозможно однозначно определить, какой именно объект информационной базы должен быть присвоен реквизиту текущей строки табличной части. Для разрешения неоднозначностей требуется реализовать экспортную процедуру ЗаполнитьСписокНеоднозначностей:

// Возвращает список подходящих объектов ИБ для неоднозначного значения ячейки.

//

// Параметры:

//   ПолноеИмяТабличнойЧасти  - Строка - Полное имя табличной части, в которую загружаются данные.

// ИмяКолонки   - Строка - Имя колонки, в который возникла неоднозначность.

//  СписокНеоднозначностей    - Массив  - Массив для заполнения с неоднозначными данными.

//  ЗагружаемыеЗначенияСтрока - Строка  - Загружаемые данные, на основании которых возникла неоднозначность.

//  ДополнительныеПараметры   - ЛюбойТип - Любые дополнительные сведения

//

Процедура ЗаполнитьСписокНеоднозначностей(ПолноеИмяТабличнойЧасти, СписокНеоднозначностей, ИмяКолонки, ЗагружаемыеЗначенияСтрока, ДополнительныеПараметры) Экспорт

КонецПроцедуры

См. пример реализации в документе \_ДемоСчетНаОплатуПокупателю.

**Особые случаи внедрения подсистемы**

**Собственный алгоритм загрузки данных**

Если для загрузки элементов справочника недостаточно стандартных средств, можно предусмотреть собственный алгоритм загрузки. Для этого требуется:

1. В справочнике создать табличный макет с именем ЗагрузкаИзФайла, в котором определить состав колонок. Для быстрого создания макета рекомендуется запустить конфигурацию и в режиме 1С:Предприятие выполнить команду по загрузке данных в этот справочник. Затем на шаге ввода данных в таблицу сохранить бланк для заполнения в MXL-файл и использовать в качестве заготовки для макета. Для загрузки контактной информации и дополнительных сведений в справочник в макете следует определить специальные колонки <Контактная информация> и <Дополнительные сведения> обозначающие место, где будут автоматически добавлены колонки с видами контактной информации объекта и его дополнительными реквизитами и свойствами.

2. В модуль менеджера справочника реализовать три экспортные процедуры: ОпределитьПараметрыЗагрузкиДанныхИзФайла, СопоставитьЗагружаемыеДанныеИзФайла и ЗагрузитьИзФайла. В них реализовать логику сопоставления и загрузки данных в реквизиты справочника.

// Устанавливает параметры загрузки данных из файла

//

// Параметры:

//     Параметры - Структура - Список параметров. Поля:

//         \* Заголовок - Строка - Заголовок окна

//         \* ОбязательныеКолонки -  Массив - Список имен колонок, обязательных для заполнения

//         \* ТипДанныхКолонки - Соответствие, Ключ - Имя колонки, Значение - Описание типа данных

//

Процедура ОпределитьПараметрыЗагрузкиДанныхИзФайла(Параметры) Экспорт

КонецПроцедуры

// Производит сопоставление загружаемых данных с данными в ИБ.

//

// Параметры:

//   ЗагружаемыеДанные - ТаблицаЗначений - таблица значений с загружаемыми данными:

//     \* СопоставленныйОбъект - СправочникСсылка - Ссылка на сопоставленный объект. Заполняется внутри процедуры

//     \* <другие колонки>     - Произвольный - Состав колонок соответствует макету "ЗагрузкаИзФайла"

//

Процедура СопоставитьЗагружаемыеДанныеИзФайла(ЗагружаемыеДанные) Экспорт

КонецПроцедуры

// Загрузка данных из файла

//

// Параметры:

//   ЗагружаемыеДанные - ТаблицаЗначений с колонками:

//     \* СопоставленныйОбъект         - СправочникСсылка - Ссылка на сопоставленный объект

//     \* РезультатСопоставленияСтроки - Строка       - Cтатусом загрузки, возможны варианты: Создан, Обновлен, Пропущен

//     \* ОписаниеОшибки               - Строка       - расшифровка ошибки загрузки данных

//     \* Идентификатор                - Число        - Уникальный номер строки

//     \* <другие колонки>             - Произвольный - Строки загружаемого файла в соответствии с макетом

// ПараметрыЗагрузки                  - Структура    - Параметры загрузки

//     \* СоздаватьНовые               - Булево       - Требуется ли создавать новые элементы справочника

//     \* ОбновлятьСуществующие        - Булево       - Требуется ли обновлять элементы справочника

// Отказ                              - Булево       - Отмена загрузки

Процедура ЗагрузитьИзФайла(ЗагружаемыеДанные, ПараметрыЗагрузки, Отказ) Экспорт

КонецПроцедуры

См. пример реализации в справочнике \_ДемоНоменклатура в демонстрационной конфигурации.

**Программное создание табличного макета для загрузки данных в табличную часть**

В случаях, когда набор колонок в шаблоне не статичен, а определяется динамически (например, зависит от текущих значений реквизитов объекта, статуса документа, значений функциональных опций и т.п.), есть возможность программно определить состав колонок табличного макета.

Для этого можно воспользоваться следующими функциями программного интерфейса:

● СформироватьОписаниеКолонок общего модуля ЗагрузкаДанныхИзФайла;

● ОписаниеКолонкиМакета и КолонкаМакета общего модуля ЗагрузкаДанныхИзФайлаКлиентСервер.

Пример реализации для табличной части Аналоги документа \_ДемоНоменклатура:

&НаКлиенте

Процедура ЗагрузитьТоварыИзФайла(Команда)

ПараметрыЗагрузки = ЗагрузкаДанныхИзФайлаКлиент.ПараметрыЗагрузкиДанных();

ПараметрыЗагрузки.ПолноеИмяТабличнойЧасти = "\_ДемоНоменклатура.Аналоги";

ПараметрыЗагрузки.Заголовок = НСтр("ru = 'Загрузка списка аналогов из файла'");

// Описание колонок для макета загрузки комплектации

ПараметрыЗагрузки.КолонкиМакета = ОписаниеКолонокМакетаДляЗагрузкиАналогов();

Оповещение = Новый ОписаниеОповещения("ЗагрузитьАналогиИзФайлаЗавершение", ЭтотОбъект);

ЗагрузкаДанныхИзФайлаКлиент.ПоказатьФормуЗагрузки(ПараметрыЗагрузки, Оповещение);

КонецПроцедуры

&НаСервере

Функция ОписаниеКолонокМакетаДляЗагрузкиАналогов();

КолонкиМакета = ЗагрузкаДанныхИзФайла.СформироватьОписаниеКолонок(Объект.Аналоги);

ЗагрузкаДанныхИзФайлаКлиентСервер.УдалитьКолонкуМакета("Аналог", КолонкиМакета);

Если Объект.ВидНоменклатуры.Наименование = "Услуга" Тогда

// У услуг нет штрихкода

Колонка = ЗагрузкаДанныхИзФайлаКлиентСервер.ОписаниеКолонкиМакета("ШтрихкодАртикул", ОбщегоНазначения.ОписаниеТипаСтрока(20), НСтр("ru = 'Артикул'"));

Иначе

Колонка = ЗагрузкаДанныхИзФайлаКлиентСервер.ОписаниеКолонкиМакета("ШтрихкодАртикул", ОбщегоНазначения.ОписаниеТипаСтрока(20), НСтр("ru = 'Штрихкод и Артикул'"));

КонецЕсли;

Колонка.ОбязательнаДляЗаполнения = Истина;

Колонка.Позиция = 1;

Колонка.Группа = "Номенклатура";

Колонка.Родитель = "Аналог";

КолонкиМакета.Добавить(Колонка);

Колонка = ЗагрузкаДанныхИзФайлаКлиентСервер.ОписаниеКолонкиМакета("Наименование", ОбщегоНазначения.ОписаниеТипаСтрока(100));

Колонка.Группа = "Номенклатура";

Колонка.Родитель = "Аналог";

Колонка.Позиция = 2;

КолонкиМакета.Добавить(Колонка);

Колонка = ЗагрузкаДанныхИзФайлаКлиентСервер.КолонкаМакета("Совместимость", КолонкиМакета);

Колонка.Позиция = 3;

Возврат КолонкиМакета;

КонецФункции

См. полностью пример реализации в справочнике \_ДемоНоменклатура в демонстрационной конфигурации.

**Настройка прав доступа пользователей**

Таблица 3.36.

| № | Роли и их назначение |
| --- | --- |
| 1. | ПолныеПрава (из подсистемы «Базовая функциональность»)  Загрузка данных из файлов в справочники |

Для загрузки данных в табличные части документов не требуются какие-либо дополнительные роли. Команды загрузки доступны тем пользователям, у которых есть права на редактирование самого документа.

**Использование при разработке конфигурации**

**Разработка дополнительных обработок для загрузки данных**

Для расширения возможностей загрузки данных из файла в справочники можно также использовать средства подсистемы «Дополнительные отчеты и обработки».

Надо создать внешнюю обработку согласно требованиям раздела «[Дополнительные отчеты и обработки](https://its.1c.ru/db/content/bsp301doc/src/3.16.%20дополнительные%20отчеты%20и%20обработки.htm?_=1542292879#_дополнительные_отчеты_и)». Затем в функции СведенияОВнешнейОбработке модуля объекта обработки описать параметры команды. Например, для добавления варианта загрузки Демо: Контрагенты (Юридические лица с контактной информацией):

// Возвращает сведения о внешней обработке.

Функция СведенияОВнешнейОбработке() Экспорт

ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.3.1");

ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();

ПараметрыРегистрации.Версия = "1.0";

НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();

НоваяКоманда.Представление = НСтр("ru = 'Демо: Контрагенты (Юридические лица с контактной информацией)'");

НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыЗагрузкаДанныхИзФайла();

НоваяКоманда.Модификатор   = Метаданные.Справочники.\_ДемоКонтрагенты.ПолноеИмя();

НоваяКоманда.Идентификатор = "ЮрЛицаКонтрагентов";

Возврат ПараметрыРегистрации;

КонецФункции

В модуль объекта обработки разместить экспортные процедуры ОпределитьПараметрыЗагрузкиДанныхИзФайла, где переопределяются настройки загрузки по умолчанию, и СопоставитьЗагружаемыеДанныеИзФайла и ЗагрузитьИзФайла, в которых реализовать логику сопоставления и загрузки данных в реквизиты справочника:

// Определяет параметры загрузки данных из файла.

//

// Параметры:

//   ИдентификаторКоманды - Строка - Имя команды, определенное в функции СведенияОВнешнейОбработке().

//   ПараметрыЗагрузки - Структура - Настройки загрузки данных:

//       \* ИмяМакетаСШаблоном - Строка - Имя макета с шаблоном загружаемых данных.

//           По умолчанию используется макет "ЗагрузкаИзФайла".

//       \* ОбязательныеКолонкиМакета - Массив - Список имен колонок обязательных для заполнения.

//

Процедура ОпределитьПараметрыЗагрузкиДанныхИзФайла(ИдентификаторКоманды, ПараметрыЗагрузки) Экспорт

Если ИдентификаторКоманды = "ЮрЛицаКонтрагентов" Тогда

ПараметрыЗагрузки.ИмяМакетаСШаблоном = "ЗагрузкаИзФайлКонтрагенты";

КонецЕсли;

КонецПроцедуры

// Производит сопоставление данных, загружаемых из файла, с данными в информационной базе

//

//   ИдентификаторКоманды - Строка - Идентификатор команды

//   ЗагружаемыеДанные - ТаблицаЗначений - таблица значений с загружаемыми данными:

//     \* СопоставленныйОбъект - СправочникСсылка.Ссылка - Ссылка на сопоставленный объект. Заполняется внутри процедуры

//     \* <другие колонки>    - Строка - Состав колонок соответствует макету "ЗагрузкаИзФайла"

//

Процедура СопоставитьЗагружаемыеДанныеИзФайла(ИдентификаторКоманды, ЗагружаемыеДанные) Экспорт

КонецПроцедуры

// Производит загрузку строки сопоставленных данных в элемент справочника.

//

//   ИдентификаторКоманды - Строка - Идентификатор команды

//   ЗагружаемыеДанные - Структура - Ключ - название колонки, Значение - Данные ячейки

//     \* СопоставленныйОбъект - СправочникСсылка.Ссылка - Ссылка на сопоставленный объект

//     \* <другие колонки>    - Строка - Строки загружаемого файла

//   ПараметрыЗагрузки - Структура - Параметры с пользовательскими установками загрузки данных

// \* Обновлять - Булево - Требуется ли создавать новые объекты

// \* Создавать - Булево - Требуется ли обновлять новые объекты

// Отказ                      - Булево       - Отмена загрузки

//

Процедура ЗагрузитьИзФайла(ИдентификаторКоманды, ЗагружаемыеДанные, ПараметрыЗагрузки, Отказ) Экспорт

КонецПроцедуры

См. пример обработки загрузки данных в демонстрационной конфигурации: раздел Администрирование – Печатные формы, отчеты и обработки – Дополнительные отчеты и обработки – Загрузка юридических лиц (с контактной информацией).

**Настройка обмена данными**

Для настройки обмена данными никаких действий не требуется, так как подсистема не предоставляет собственных данных.